EXCEL 2007 FUNÇÕES CONTAR (Count Functions)

Existem várias formas de contar valores ou dados. Para executar esta tarefa, podemos utilizar várias funções além da função contar.
There are several ways to count values ​​or data. To perform this task, we can use various functions besides the function count.

Função CONTAR / COUNT Function
Conta o número de células que contêm números
Count the number of cells that contain numbers

Fórmula em F2: =CONTAR(A2:E2) / =COUNT(A2:E2)


Função CONTAR.VAL / COUNTA Function
Conta o número de células que contêm valores (não em branco)
Count the number of cells with values (not blank)

Fórmula em F2: =CONTAR.VAL(A2:E2) / =COUNTA(A2:E2)

Função CONTAR.VAZIO / COUNTBLANK Function
Conta o número de células em branco
Count the number of blank cells

Fórmula em F2: =CONTAR.VAZIO(A2:E2) / =COUNTBLANK(A2:E2)

Função CONTAR.SE / COUNTIF Function 
Conta o número de células que respeitam uma dada condição
Count the number of cells that meet a certain condition
Fórmula em F2: =CONTAR.SE(A2:E2;"BBB") / COUNTIF (A2:E2;"BBB")

Em alternativa, podemos usar a Função SOMARPRODUTO
As alternative, we can use SUMPRODUCT Function
Fórmula em F2:=SOMARPRODUTO(--(F1=A2:E2)) / =SUMPRODUCT(--(F1=A2:E2))


Função CONTAR.SE.S / COUNTIFS Function
Aplica critérios a células através de múltiplos intervalos e conta o número de vezes que todos os critérios são satisfeitos
Applies criteria to cells across multiple ranges and counts the number of times all criteria are met

=CONTAR.SE.S(B2:G5;"4") / =COUNTIFS(B2:G5;"4")
Conta quantas vezes o nº 4 existe na tabela
Counts how many cells with nº 4 in the table
=CONTAR.SE.S(B2:B5;"4";E2:E5;"7") / =COUNTIFS(B2:B5;"4";E2:E5;"7")

Conta quantas vezes os nº 4 e 7 são comuns em Z1 e Z4 na mesma linha
Counts how many cells, from Z1 and Z4,  with nº 4 and nº 7 in the same table row
=CONTAR.SE.S(A2:G2;"<5";A2:G2;">2") / =COUNTIFS(A2:G2;"<5";A2:G2;">2")

Conta quantos números maiores que 2 e menores que 5 existem na linha A
Counts how many cells in row A with numbers <5 and >2

Técnicas de CONTAR com outras funções
COUNT Techniques using other fuctions


{=SOMA(SE(FREQUÊNCIA(CONTAR.SE(Zon2; "<"&Zon2);CONTAR.SE(Zon2; "<"&Zon2))>0;SE(CONTAR.SE(Zon1;Zon2)>0; 1; 0); ""))}
Conta os valores comuns às duas listas (Zon1 e Zon2), excluindo os valores repetidos
{=SUM(IF(FREQUENCY(COUNTIF(Zon2; "<"&Zon2);COUNTIF(Zon2; "<"&Zon2))>0;IF(COUNTIF(Zon1;Zon2)>0; 1; 0); ""))}
Count common UNIQUE DISTINCT cell values between Zon2 and Zon1 (repeated values excluded)

{=SOMA(SE(CONTAR.SE(Zon1;Zon2)>0; 1; 0))}
Conta TODOS os valores comuns em Zon2 entre as duas listas (Zon1 e Zon2)
{=SUM(IF(COUNTIF(Zon1;Zon2)>0; 1; 0))}
Count ALL common cell values between Zon2 and Zon1


NOTA:
Para ser mais rápido e mais fácil escrever a fórmula, devemos nomear cada intervalo de dados.
Por exemplo, para Zon1: Seleccionar o intervalo, Clicar o botão direito, escolher Nomear Intervalo, escrever Zon1
As fórmulas utilizadas são FÓRMULAS DE MATRIZ. Para accionar uma Fórmula de Matriz deve executar o seguinte:
Escrever a fórmula =SOMA(SE(CONTAR.SE(Zon1;Zon2)>0; 1; 0)) Premir Ctrl+Shift+Enter

NOTE:
To write formulas in a faster and easier way, you should name each data range.
For example, Zon1: Select the range, right click mouse botton, Choose Name a Range, Write Zon1
These are ARRAY FORMULAS. To execute na Array Formula you must:
Write =SUM(IF(COUNTIF(Zon1;Zon2)>0; 1; 0)) Press Ctrl+Shift+Enter
=SOMARPRODUTO(--("Europe"=A2:A8))
Conta as células que contêm Europe no intervalo A2:A8
=SOMARPRODUTO(--("Europe"=A2:A8))
Count cells in range C8:C14 containing Europe    
   
=SOMARPRODUTO(--(A2:A8="America");--(B2:B8="Ca"))   
Conta as linhas cujas células das colunas Client e Prod contenham os critérios pretendidos   
=SOMARPRODUTO(--(A2:A8="America");--(B2:B8="Ca"))
Count rows which cell values contain defined criteria (America in Client Range and Ca in Prod Range)   
   
=SOMARPRODUTO(--(A2:A8="Europe");--(B2:B8="Ri");--(C2:C8>130);--(C2:C8<190))   
Conta as linhas cujas células das colunas Client e Prod contenham os critérios pretendidos e com valores entre 130 e 190  
=SOMARPRODUTO(--(A2:A8="Europe");--(B2:B8="Ri");--(C2:C8>130);--(C2:C8<190))
Count rows which cell values contain defined criteria (Europe in Client Range and Ri in Prod Range), and values between 130 and 190   
   
NOTA:   
Para ser mais rápido e mais fácil escrever a fórmula, devemos nomear cada intervalo de dados.   
Por exemplo, para Client: Seleccionar o intervalo, Clicar o botão direito, escolher Nomear Intervalo, escrever Client   
As fórmulas ficariam assim   
=SOMARPRODUTO(--("Europe"=Client))   
=SOMARPRODUTO(--(Client="America");--(Prod="Ca"))   
=SOMARPRODUTO(--(Client="Europe");--(Prod="Ri");--(Val>130);--(Val<190))
   
NOTE:   
To write formulas in a faster and easier way, you should name each data range.   
For example, Client: Select the range, right click mouse botton, Choose Name a Range, Write Client   
Formulas would be writen like this   
=SUMPRODUCT(--("Europe"=Client))   
=SUMPRODUCT(--(Client="America");--(Prod="Ca"))   
=SUMPRODUCT(--(Client="Europe");--(Prod="Ri");--(Val>130);--(Val<190))   






Comentários

  1. Estou com dificuldade em contar numa tabela valores superiores a x mas inferiores a Y, será que me podem ajudar?Obg

    ResponderEliminar
    Respostas
    1. Olá
      A resposta está acima descrita:
      =CONTAR.SE.S(A1:A10;"x")

      Eliminar

Enviar um comentário

Mensagens populares deste blogue

EXCEL 2007 - FUNÇÕES PARA CALCULAR HORAS (Functions to Calculate Hours)

CONVERTER HORAS EM DIAS DE TRABALHO (Convert Hours to Workdays)

EXCEL - SUBSTITUIR PONTO POR VÍRGULA (Changing comma to point) ou vice-versa